Query modifiers: Refining Your Search

SELECT DISTINCT ?birthdate ?name WHERE {
  ?person cwrc:hasGender cwrc:woman;
          cwrc:hasBirthDate ?birthdate;
  		  skos:altLabel ?name.
}

This query returns the names and birthdays of women with no duplicate entries.

SELECT ?name ?birthDate ?deathDate ?age WHERE {
  ?person rdfs:label ?name;
          cwrc:hasDeathDate ?deathDate;
          cwrc:hasBirthDate ?birthDate.
  BIND(?deathDate - ?birthDate as ?ageInDays).
  BIND(?ageInDays/365.2425 AS ?ageInYears).
  BIND(FLOOR(?ageInYears) AS ?age).

}

This query returns the names and ages of people in the database. The age is calculated using the BIND keyword to assign values to variables such as date of birth, date of death, and ageInDays, so operations can be performed on them without overwriting the variable each time.

SELECT ?name ?birthDate WHERE {
    ?person cwrc:hasBirthDate ?birthDate ;
            cwrc:hasGender cwrc:woman;
            rdfs:label ?name.
FILTER ((?birthDate >= '1900-01-01'^^xsd:date)) .
} 

This query returns names of women with birthdates after January 1, 1900.

SELECT ?name WHERE {
    ?person cwrc:hasBirthDate ?birthDate ;
            cwrc:hasGender cwrc:woman;
            rdfs:label ?name.
    FILTER NOT EXISTS {
        ?person cwrc:hasBirthDate "1775-12-16"^^xsd:date
    }
}

This query returns names of women except for those with the birthday December 16, 1776 (Jane Austen).

SELECT ?obj ?snippet WHERE {
  GRAPH  {
   ?context ?pred ?obj;
            cwrc:contextFocus ?person;
      		oa:hasTarget ?target;
            rdf:type cwrc:DeathContext.
  ?person rdfs:label "Donne, John".
}.
  ?target oa:hasSelector/oa:refinedBy/oa:exact ?snippet.
}

This query will return snippets relating to John Donne's death. It does so by using GRAPH to get the context from the BiographyV2Beta database where it is stored.

SELECT ?occupation (COUNT(?person) AS ?numPerProf) WHERE {
    ?person cwrc:hasGender cwrc:woman;
        cwrc:hasOccupation ?occupation.
}
GROUP BY ?occupation

This query returns occupations of women in CRWC. The query first finds all the women with occupations, groups them by their occupations (using GROUP BY), and then counts the number of people in each group. These counts will be displayed in the results table in a column labeled "numPerProf", the number of people in each profession.

SELECT ?name WHERE { 
    ?person cwrc:hasGender cwrc:woman .
    ?person rdfs:label ?name .
}LIMIT 10

This query returns the first ten names of women.

SELECT ?name WHERE {
  ?person cwrc:hasGender cwrc:woman .
  ?person rdfs:label ?name .
  MINUS {
    ?person rdfs:label "Askew, Anne".
  }.
} 

This query returns names of women, except those named "Anne Askew".

SELECT ?name WHERE {
  ?person cwrc:hasGender cwrc:woman .
  ?person rdfs:label ?name .

}OFFSET 10

This query returns names of women, starting at the eleventh name.

SELECT ?name ?deathDate WHERE {
  ?person cwrc:hasGender cwrc:woman;
   rdfs:label ?name .
  OPTIONAL {?person cwrc:hasDeathDate ?deathDate}.
}

This query returns names of women and their date of death. If they do not have a date of death, their name will still be displayed, but the column for date of death will be empty for that row.

SELECT ?name ?birthDate WHERE {
    ?person cwrc:hasBirthDate ?birthDate.
    ?person rdfs:label ?name .

}ORDER BY ?birthDate

This query returns names of people, ordered by their date of birth.

SELECT ?name ?birthDate WHERE {
    VALUES ?name {"Anne" "Mary"}
  ?person cwrc:hasBirthDate ?birthDate.

}

This query returns names, these names can either be Anne or Mary.

SELECT ?name ?occupation WHERE {
  ?person rdfs:label ?name.
  {?person cwrc:hasPaidOccupation ?occupation.}
  UNION
  {?person cwrc:hasVolunteerOccupation ?occupation.}
}

This query returns the names and occupations of people who have a volunteer occupation, and people who have paid occupations. By using UNION, the two kinds of occupations are displayed in the same column, rather than needing to have separate columns for each type of occupation.